Comparison of Swan results with measurements
Two Swan computations were made for the Haringvliet area, one
without current, the other with zero current.
It turned out that the two sets of results were not identical, unfortunately.
See the Swan control file
for the case with zero current.
With the OPGraph control file shown below, both computational results
are compared with observations also available for this area.
project 'SWAN conf. test' 'f01'
! this procedure generates a plot where results of 2 Swan runs
! are compared with observations
! the upper panel is for Hs, the lower panel for period
outfile 'f01_parms.eps'
option frame=0 plot EPS
page panels 1, 2
transf 'sta' lin 0, 9
transf 'Hs' lin 0, 4.2
transf 'Tm' lin 0, 8
CHAR .27
appearance 33 pen=2 thickn=0.05 syms=0.32
for '[var]' is 'Hs' 'Tm' &
coupled '[num]' is '1' '2' &
coupled '[Scol]' is '4' '5' &
coupled '[Vcol]' is '2' '3' &
do
panel num [num] x 'sta' y '[var]'
axis x ' stations ' LABEL TICKS AT 1 2 3 4 5 6 7 8
axis y '[var]' auto
if '[num]' is '1'
curve 1 panel 0.36, 1, 0.36, 0.88, 1, 0.88
text panel 0.4, 0.9, 0. 'F01, Haringvliet: 23:00 UTC, Oct. 14, 1982'
endif
file 'verif.dat\hvl2300a.dat' 1 simple
obtain 'st' 1 1
obtain '[var]' 1 [Vcol]
graph 33 x 'st' y '[var]'
if '[num]' is '2'
legend 'Observations around 23:00 hrs' panel 0.1, 0.21, 1
curve app=1 panel 0, 0.27, 0.6, 0.27, 0.6, 0.
endif
file 'verif.dat\hvl2300b.dat' 1 simple
obtain 'st' 1 1
obtain '[var]' 1 [Vcol]
graph 33 x 'st' y '[var]'
appearance 22 pen=3 thickn=0.05 syms=0.32
appearance 24 pen=3 thickn=0.05 syms=0.32
for '[case]' is 'a', 'b' &
coupled '[ltyp]' is '22','24' &
do
file 'f01[case].tab' 2 simple
obtain '[var]' 2 [Scol]
assignto 'stat' series 1, 'numcomp([var])', 'numcomp([var])'
graph [ltyp] x 'stat' y '[var]'
if '[num]' is '2'
if '[case]' is 'a'
legend 'SWAN, no current' panel 0.1, 0.09, 1
endif
if '[case]' is 'b'
legend 'SWAN, current=0' panel 0.1, 0.03, 1
endif
endif
endfor
endfor
INCLUDE '..\incl\copyrgt.opg'
test 0
! the procedure below generates a plot file showing 1d spectra
! computed by runs F01a and F01b
! with observations of spectra at 7 buoys and one wave staff
! there is a panel for each buoy
outfile 'f01_spec.eps'
option frame=0 plot EPS
page panels= 2, 4
char 0.2
transf 'f' lin 0, 0.6
for '[pan]' is '1' '2' '3' '4' '5' '6' '7' '8' &
coupled '[sta]' is 'Wav' 'Wr1' 'Wr2' 'Wr3' 'Wr4' 'Wr5' 'Wr6' 'E75' &
coupled '[vrt]' is '20' '15' '10' '10' '1' '2' '6' '1' &
coupled '[hr1]' is '23' '21' '22' '22' '22' '22' '23' '23' &
coupled '[mi1]' is '00' '00' '30' '50' '50' '50' '10' '00' &
coupled '[hr2]' is ' ' '01' ' ' ' ' '23' '23' ' ' ' ' &
coupled '[mi2]' is ' ' '30' ' ' ' ' '10' '10' ' ' ' ' do
transf 'e' lin 0, [vrt]
panel num [pan] x 'f' y 'e'
axis x 'f' auto
axis y 'E' auto
text pan 0.5, 0.87, 0, 'station [sta]'
file 'f01B.spc' 1 swan
obtain 'AFREQ' From 1
obtain 'VaDens' from 1 for 'LOCATIONS' [pan]
graph 2 x 'AFREQ' Y 'VaDens'
if '[pan]' is '5'
legend 'SWAN, current=0' panel 0.15, 1.05, 1
endif
file 'f01A.spc' 1 swan
obtain 'AFREQ' From 1
obtain 'VaDens' from 1 for 'LOCATIONS' [pan]
graph 3 x 'AFREQ' Y 'VaDens'
if '[pan]' is '1'
legend 'SWAN, no current' panel 0.15, 1.05, 1
endif
file 'verif.dat\[sta]_[hr1][mi1].dat' 1 simple
obtain 'AFREQ' From 1 1
obtain 'VaDens' from 1 2
graph 4 x 'AFREQ' Y 'VaDens'
legend '[hr1]:[mi1]' panel 0.5, 0.77, 1.
if '[hr2]' isnot ' ' then
file 'verif.dat\[sta]_[hr2][mi2].dat' 1 simple
obtain 'AFREQ' From 1 1
obtain 'VaDens' from 1 2
graph 4 x 'AFREQ' Y 'VaDens'
legend '[hr2]:[mi2]' panel 0.5, 0.67, 1.
endif
endfor
INCLUDE '..\incl\copyrgt.opg'
stop
Two pictures result from this OPGraph job; one is called 'F01_parms.ps';
it shows the deviation between the computed wave parameters Hs and Tm01
and the measurements made by 7 wave buoys and a wave staff. One buoy provided
directional information; this was used as boundary condition.
It is noted that the computations are made for time 23.00; observations for this time
were not present at all buoys; therefore in some locations two observations at
instants around 23.00 were used.
The second picture is called 'F01_spec.ps'; it shows a comparison between computed 1-d spectra and observed spectra. These observed spectra were read from files of which the name consisted of the station name and the time of observation.
